Rob van der Woude's Scripting Pages
Powered by GeSHi

Source code for creationdate.bat

(view source code of creationdate.bat as plain text) 

  1. @ECHO OFF
  2. IF "%~1"=="" GOTO Syntax
  3.  
  4. ECHO.%* | FIND.EXE "/?" >NUL
  5. IF NOT ERRORLEVEL 1 GOTO Syntax
  6.  
  7. exiftool.exe -ver >NUL
  8. IF ERRORLEVEL 1 (
  9. 	ECHO.
  10. 	ECHO ←[0;31mERROR:←[0m: exiftool.exe not found
  11. 	GOTO Syntax
  12. )
  13.  
  14. FOR %%A IN (%*) DO (
  15. 	FOR %%B IN ("%%~A") DO (
  16. 		FOR /F "tokens=1* delims=:" %%C IN ('exiftool.exe -CreateDate "%%~A" 2^>NUL ^| FIND.EXE ":" ^|^| exiftool.exe -FILE:*Creat* "%%~A" 2^>NUL') DO (
  17. 			FOR /F "tokens=1,2 delims=Z+ " %%E IN ("%%~D") DO (
  18. 				ECHO %%B	%%E %%F
  19. 			)
  20. 		)
  21. 	)
  22. )
  23. GOTO:EOF
  24.  
  25.  
  26. :Syntax
  27. ECHO.
  28. ECHO CreationDate.bat,  Version 1.00
  29. ECHO Use ExifTool to show the creation date of a file or multiple files
  30. ECHO.
  31. ECHO Usage:  Creationdate.bat  filespec  [ filespec  [ filespec ... ] ]
  32. ECHO.
  33. ECHO Where:  filespec   is a single file or a list of files to be investigated
  34. ECHO                    (wildcards allowed)
  35. ECHO.
  36. ECHO Notes:  Requires Phil Harvey's ExifTool:
  37. ECHO         ←[0;1;30mhttps://exiftool.org/←[0m
  38. ECHO         Result is in tab delimited format: {filename}{tab}{date time}
  39. ECHO         Return code ("Errorlevel") -1 in case of (command line) errors,
  40. ECHO         otherwise 0.
  41. ECHO.
  42. ECHO Written by Rob van der Woude
  43. ECHO https://www.robvanderwoude.com
  44. EXIT /B 1
  45.  

page last modified: 2024-04-16; loaded in 0.0062 seconds