@ECHO OFF
IF "%~1"=="" GOTO Syntax

ECHO.%* | FIND.EXE "/?" >NUL
IF NOT ERRORLEVEL 1 GOTO Syntax

exiftool.exe -ver >NUL
IF ERRORLEVEL 1 (
	ECHO.
	ECHO ERROR:: exiftool.exe not found
	GOTO Syntax
)

FOR %%A IN (%*) DO (
	FOR %%B IN ("%%~A") DO (
		FOR /F "tokens=1* delims=:" %%C IN ('exiftool.exe -CreateDate "%%~A" 2^>NUL ^| FIND.EXE ":" ^|^| exiftool.exe -FILE:*Creat* "%%~A" 2^>NUL') DO (
			FOR /F "tokens=1,2 delims=Z+ " %%E IN ("%%~D") DO (
				ECHO %%B	%%E %%F
			)
		)
	)
)
GOTO:EOF


:Syntax
ECHO.
ECHO CreationDate.bat,  Version 1.00
ECHO Use ExifTool to show the creation date of a file or multiple files
ECHO.
ECHO Usage:  Creationdate.bat  filespec  [ filespec  [ filespec ... ] ]
ECHO.
ECHO Where:  filespec   is a single file or a list of files to be investigated
ECHO                    (wildcards allowed)
ECHO.
ECHO Notes:  Requires Phil Harvey's ExifTool:
ECHO         https://exiftool.org/
ECHO         Result is in tab delimited format: {filename}{tab}{date time}
ECHO         Return code ("Errorlevel") -1 in case of (command line) errors,
ECHO         otherwise 0.
ECHO.
ECHO Written by Rob van der Woude
ECHO https://www.robvanderwoude.com
EXIT /B 1